ユーザーマニュアル入手

ハイデンハインのサイトでは、コントローラのマニュアルがダウンロードできます。

ホームページから、「Service&Support」⇒ 「Downloads」⇒ 「Documentation」と進み
下へスクロールして、右側の「Categories」で「CNC Controls」で各言語に対応したマニュアルがダウンロードできます。
ただ残念ながら、日本語はないみたいです。
私は、こちらをダウンロードしました。

ドリル・タップサイクル

ドリルやタップ用のサイクルは、ダウンロードしたマニュアルでは、
８．３項目、ページ３３１～　に説明があります。
英語ですが、単語とアイコンでだいたいわかると思います

• 240 CENTERING _______________________________Page 333
• 200 DRILLING _________________________________Page 335
• 201 REAMING _________________________________Page 337
• 202 BORING ___________________________________Page 339
• 203 UNIVERSAL DRILLING _____________________Page 341
• 204 BACK BORING _____________________________Page 343
• 205 UNIVERSAL PECKING ______________________Page 346
• 208 BORE MILLING _____________________________Page 349
• 206 TAPPING NEW _____________________________Page 351
• 207 RIGID TAPPING NEW ______________________Page 353
• 209 TAPPING W/ CHIP BRKG __________________Page 355
• 262 THREAD MILLING _________________________Page 359
• 263 THREAD MLLNG/CNTSNKG _______________Page 361
• 264 THREAD DRILLING/MLLNG _______________Page 365
• 265 HEL.THREAD DRLG/MLG __________________Page 369
• 267 OUTSIDE THREAD MLLNG ________________Page369

ファナックの固定サイクルに比べるとかなり豊富なのがわかると思います。

スレッドミル

ねじ切りサイクル。
国内では、OSGのプラネットカッターが有名です。
加工時間は増加しますが、破損時のリスク軽減や高硬度材へのネジ加工には有効だと思います。
特に、超硬材へのネジ加工を切削で行うには、現在ではこの方法しかないように思います！
では、NCプログラムはどうやって作成するでしょう。
国内機の場合、CAMが対応している場合にはその機能を利用したり、工具メーカーが公開している
支援ソフトなどを利用したり、ユーザー側でカスタムマクロを作成したりだと思いますが、ハイデンハインには、ねじ切りサイクルがすでに準備されています。

Cycle 262、Page 359 ～に説明があります。
サイクルの使用方法は、後ほど説明しますが、「Q」で始まる指令は変数で、Qパラメータと呼ばれています。
ファナックの「#」と同様です。
この例では、「Q355」で工具の種類、「Q239」でネジピッチ、「Q201」でネジ深さ、
「Q200」でＲ点位置などが、この図で分かりますね。
これらの変数を設定する事で、ねじ切りを行うことができます。

ポケットサイクル

穴加工だけではありません。
円や長方形、スロット形状もサイクルが用意されています。
ポケット用のサイクルは、ダウンロードしたマニュアルでは、
８．４項目、ページ３８２～　に説明があります。

• 251 RECTANGULAR POCKET ____________________Page 383
• 252 CIRCULAR POCKET _________________________Page 388
• 253 SLOT MILLING ______________________________Page 392
• 254 CIRCULAR SLOT ____________________________Page 397
• 212 POCKET FINISHING ________________________Page 402
• 213 STUD FINISHING __________________________Page 404
• 214 C. POCKET FINISHING _____________________Page 406
• 215 CIRCULAR STUD FINISHING _______________Page 406
• 210 SLOT RECIP. PLNG _________________________Page 410
• 211 CIRCULAR SLOT ____________________________Page 413

かなり豊富なサイクルが用意されています。
何種類かのサイクルを組み合わせる事で、ある程度の加工はCAMがなくてもできそうです。

補正

サイクルからは少し外れますが、ハイデンハインは工具を「Tool Table」というテキストファイルで管理しています。
そのため、任意の工具を交換しただけで、コントローラは工具情報を「Tool Table」から取得します。
内容で必須なのは、「工具長さ」「工具径」ですが、この値は手動で入力してもいいですが
工具自動測定仕様であれば、自動的に入力されます。
したがって、工具交換しただけで、工具長補正は完成し、工具径補正が必要なNCデータを実行する場合「Tool Table」の値を元に、工具径補正が行われます。
これは、上記で説明した、「スレッドミル」や「ポケット」サイクルにも対応されます。
D番号を忘れた！などのトラブルはかなり少なくなります。
ちょっと面白い仕様に、切込み角度の項目があります。
これは、指定工具が切込み可能な場合、切込み角度を設定する項目です。
傾斜切込みを行うサイクルを使用する場合、このデータが参照されます。
このように、ハイデンハインでは使用工具はどのような工具なのかを登録しておき
工具交換する事で、その内容が自動的に反映される仕組みです。
工具交換しただけでと言うところが、重要なポイントで交換すれば、
工具長補正は完了状態なので、ワークの任意のZ点に手パ（ハンドル）で簡単に移動できます。
これは、タッチプローブでも同じです。

タッチプローブサイクル

プローブ測定用のサイクルも用意されています。
ただし、上記で紹介したマニュアルには、載っていませんでした。
こちらのマニュアルにありました。
タッチプローブ機能はオプションだからかもしれません。
ただ、特にEUではタッチプローブは必須の考えが強いように思います。

これは、ワーク測定用のサイクルですが、こちらもかなり充実していますね。
最近ファナック機はご無沙汰なので最近の状況は分かりませんが、
私が今までで立ち上げた、タッチプローブ仕様のファナック機では、
自動ワーク座標系設定やワーク測定は、機械メーカーのサービスマンが提供してくれた
マクロプログラムを使用する方法で教わりました。
ただどのメーカーも、単純にタッチした底面のワーク原点からの深さを表示するマクロがありませんでした。
例えば、ポケットの掘り込み加工後には、底面にタッチして、その深さを測定したくなります。
提供していただいたマクロの中には、２点を測定してその段差を出すマクロはありましたが、
やはり加工中では単純にタッチしただけで深さが知りたいですね。
これは、タッチプローブには、工具長の概念があまりないのも要因のように思います。
しょうがないので、カスタムマクロで自作しましたが、ハイデンハインには上記のような
豊富なサイクルが用意されています。
サイクルを使うと、加工後自動測定するプログラムも比較的簡単に作成可能ですし
制御機提供のサイクルなので、おそらく、違うメーカーの機械や
違うメーカーの測定器であっても、同じプログラムで測定できると思います。

プログラム例

サイクル定義

サイクルを利用するには、まず「CYCLE DEF サイクル番号」でサイクルの種類を指定し、
Qパラメータで条件を設定します。
「;」の右側はコメントになります。
また行末の「~」は次の行と連続している意味です。
先頭の「18」は行番号ですが、すべてが「18行」の一行です。
見やすくするための仕様ではないかと思っています。
マニュアルではコメントが英語ですがだいたい理解できると思います。

18 CYCL DEF 200 DRILLING ~
   Q200=+5 ;SET-UP CLEARANCE ~
   Q201=-19 ;DEPTH ~
   Q206=400 ;FEED RATE FOR PLUNGING ~
   Q202=+19 ;PLUNGING DEPTH ~
   Q210=0 ;DWELL AT TOP ~
   Q203=+0 ;SURFACE COORDINATE ~
   Q204=+50 ;2ND SET-UP CLEARANCE ~
   Q211=0 ;DWELL AT BOTTOM

この例は、ドリルサイクルですが、ファナックの「G82」と「G83」が合体したようなサイクルです。

加工位置

サイクルへは、「CYCL CALL POS」「M99」「 CYCL CALL PAT」の３種類の方法で加工位置を指定します
サイクルは、最後に定義されたものが、「CYCL CALL」により呼び出されます。
「CYCL CALL POS」で加工位置を定義します。

12 CYCL CALL POS X+30 Y+20 Z+0 FMAX M3
13 CYCL CALL POS X+80 Y+50 Z+0 FMAX

「M99」指令により、移動指令で移動した位置でサイクルを実行する事もできます

12 L X+30 Y+20 FMAX M3
13 CYCL CALL
14 L X+80 Y+50 FMAX M99
15 L Z+100 FMAX M2

「FMAX」は「早送り」の意味です。
「 CYCL CALL PAT」 は事前に、加工位置を書きだしたファイルを用意し、
そのファイルを指定する方法です。
センターとドリルのような、同じ位置に複数のサイクルを使用する場合に便利です。

6 TOOL CALL 1 Z S5000 
7 L Z+10 RO F5000 
8 SEL PATTERN “TAB1” 
9 CYCL DEF 200 DRILLING ~
  Q200=2 ;SET-UP CLEARANCE ~
  Q201=-2 ;DEPTH ~
  Q206=150 ;FEED RATE FOR PLNGNG ~
  Q202=2 ;PLUNGING DEPTH ~
  Q210=0 ;DWELL TIME AT TOP ~
  Q203=+0 ;SURFACE COORDINATE  ~
  Q204=10 ;2ND SET-UP CLEARANCE  ~
  Q211=0.2 ;DWELL TIME AT DEPTH ~
10 CYCL CALL PAT F5000 M3 ;　Cycle call in connection with point table TAB1.PNT
11 L Z+100 R0 FMAX M6
12 TOOL CALL 2 Z S5000

加工位置ファイル「Point Table」は、「SEL PATTERN」で指定します。
呼び出し元と同じディレクトリにない場合には、フルパスで指定できます

SEL PATTERN “TNC:\DIRKT5\NUST35.PNT”

Fusion360 で出力してみた

Fusion360、ポストライブラリには、「Heidenhain」用ポストも用意されています。
プレート素材に、適当な穴を開けたモデルを用意し、CAM処理させてみました。

0 BEGIN PGM 1001 MM
1 BLK FORM 0.1 Z X-150 Y-100 Z-50
2 BLK FORM 0.2 X+150 Y+100 Z+0
3 ;-------------------------------------
4 ;Tools
5 ; #92 D=20 - ZMIN=-51 - ZMAX=+50 - drill
6 ;-------------------------------------
7 ;
8 M5
9 TOOL CALL 92 Z S1590
10 L M140 MB MAX
11 M3
12 L X-110 Y-70 R0 FMAX
13 L Z+50 R0 FMAX
14 M7
15 CYCL DEF 32.0 TOLERANCE
16 CYCL DEF 32.1
17 CYCL DEF 200 DRILLING ~
   Q200=+5 ;SET-UP CLEARANCE ~
   Q201=-51 ;DEPTH ~
   Q206=160 ;FEED RATE FOR PLUNGING ~
   Q202=+20 ;INFEED DEPTH ~
   Q210=0 ;DWELL AT TOP ~
   Q203=+0 ;SURFACE COORDINATE ~
   Q204=+50 ;2ND SET-UP CLEARANCE ~
   Q211=0 ;DWELL AT BOTTOM
18 L FMAX M99
19 L Y+70 FMAX M99
20 L X+110 FMAX M99
21 L Y-70 FMAX M99
22 L Z+50 FMAX
23 M9
24 M5
25 L M140 MB MAX
26 M30
27 END PGM 1001 MM

すごいですね～
私がハイデンハイン制御の５軸を立ち上げてた時には、穴あけデータは、
サイクルで出力できないCAMもあったと記憶しています。
深穴サイクルなど、直線補間「G01」でサイクル動作を置き換えたデータでした。
Fusion360のポストは、ハイデンハインサイクルの勉強にも使えそうです。

M12のタップ加工をプログラム化

M12のタップ加工行うＮＣプログラムをサイクルを組み合わせて作ってみました。
加工位置用のファイル「P1.pnt」を編集する事で、任意箇所へタップ加工ができます。
「P1.pnt」 は、制御機から作成できます。
マニュアルの「Point Tables」を参照してください。
たぶん、エディタなどでテキストを作成しても、使用できると思いますが
最初は書式がわからないと思うので、まずは制御機で作成すればテキスト化されるので
そのテキストファイルを修正する方法が簡単だと思います。
ただし、実機に触れる環境ではないので、検証できておりません。
万が一、使用する場合には、十分確認してください。

もし、実証できる方がいらっしゃれば、不具合点などコメントいただければ、助かります！

P1.PNT

BEGIN P1 .pnt MM
NR    X       Y       Z 
0     +31.5   -14     +0 
1     -15     -40     +0 
2     -31.5   +14     +0 
3     +15     +40     +0 
[END]

M12_SKD11.h

0  BEGIN PGM M12_SKD11 MM 
1  BLK FORM 0.1 Z  X+0  Y+0  Z-80
2  BLK FORM 0.2  X+150  Y+25  Z+0
3  * --------------------------------
4  CYCL DEF 247 DATUM SETTING ~
    Q339=+1    ;DATUM NUMBER
5  L  A+0  C+0 F3000 M21
6  ;;;;;;;;;;;;;;;;;;;;;;
7  ;;;; CENTER ;;;;;;;;;;
8  ;;;;;;;;;;;;;;;;;;;;;;
9  Q1 = 45 ;Tool
10 Q2 = 640 ;SP
11 Q3 = 80 ;F_Feed
12 Q4 = -0.6 ;Z_Depth
13 ;;;;;;;;;;;;;;;;;;;;;;
14 ;;;; DRILL D=10.2 ;;;
15 ;;;;;;;;;;;;;;;;;;;;;;
16 Q5 = 101 ;Tool
17 Q6 = 620 ;SP
18 Q7 = 120 ;F_Feed
19 Q8 = -25 ;Z_Depth
20 Q9 = 10 ;Q_Peck
21 ;;;;;;;;;;;;;;;;;;;;;;
22 ;;;; CHAMFER ;;;;;;;;;
23 ;;;;;;;;;;;;;;;;;;;;;;
24 Q30 = 46 ;Tool
25 Q31 = 2200 ;SP
26 Q32 = 240 ;F_Feed
27 Q33 = 0.5 ;Chanfer_Length
28 Q34 = 1.5 ;Distance
29 Q35 = Q33 + Q34 ;Depth
30 Q36 = 8 ;Coolant
31 Q37 = 12 ;Hole DIA
32 ;;;;;;;;;;;;;;;;;;;;;;
33 ;;;; TAPP M12 ;;;;;;;
34 ;;;;;;;;;;;;;;;;;;;;;;
35 Q10 = 104 ;Tool
36 Q11 = 120 ;SP
37 Q12 = -10 ;Z_Depth
38 Q13 = 1.75 ;Pitch
39 Q14 = 8 ;Coolant
40 ;;;;;;;;;;;;;;;;;;;;;;
41 * --------------------------------
42 ;;;; CENTER LBL 1 ;;;;;;;;;;;;;;
43 ;;;; DRILL LBL 2 ;;;;;;;;;;;;;;
44 ;;;; C LBL 3 ;;;;;;;;;;;;;;
45 ;;;; TAPP LBL 4 ;;;;;;;;;;;;;;
46 * --------------------------------
47 FN 9: IF +1 EQU +1 GOTO LBL 1
48 * --------------------------------
49 ;;;; SET POSITION ;;;;;;;;;;;;;;;
50 LBL 11
51 SEL PATTERN "P1.pnt"
52 CYCL CALL PAT F5000
53 M5 M9
54 L M140 MB MAX
55 LBL 0
56 * --- CENTER -----------------------
57 LBL 1
58 * - CENTER
59 TOOL CALL Q1 Z SQ2
60 M9
61 CYCL DEF 200 DRILLING ~
    Q200=+5    ;SET-UP CLEARANCE ~
    Q201=+Q4   ;DEPTH ~
    Q206=+Q3   ;FEED RATE FOR PLNGNG ~
    Q202=+Q4   ;PLUNGING DEPTH ~
    Q210=+0    ;DWELL TIME AT TOP ~
    Q203=+0    ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q211=+0    ;DWELL TIME AT DEPTH
62 L M140 MB MAX
63 L  X+0  Y+0 F8000 M3
64 L  Z+50 F8000
65 M0
66 M13
67 CALL LBL 11
68 LBL 0
69 * ---DRILL ----------------------
70 LBL 2
71 TOOL CALL Q5 Z SQ6
72 M9
73 CYCL DEF 200 DRILLING ~
    Q200=+5    ;SET-UP CLEARANCE ~
    Q201=+Q8   ;DEPTH ~
    Q206=+Q7   ;FEED RATE FOR PLNGNG ~
    Q202=+Q9   ;PLUNGING DEPTH ~
    Q210=+0    ;DWELL TIME AT TOP ~
    Q203=+0    ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q211=+0    ;DWELL TIME AT DEPTH
74 L M140 MB MAX
75 L  X+0  Y+0 F8000 M3
76 L  Z+50 F8000
77 M0
78 M13
79 CALL LBL 11
80 LBL 0
81 * --- CHAMFER -------------------
82 LBL 3
83 TOOL CALL Q30 Z SQ31 DR+Q34
84 M9
85 L M140 MB MAX
86 L  X+0  Y+0 F8000
87 L  Z+50 F5000
88 CYCL DEF 208 BORE MILLING ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q201=-Q35  ;DEPTH ~
    Q206=+Q32  ;FEED RATE FOR PLNGNG ~
    Q334=+2    ;PLUNGING DEPTH ~
    Q203=+0    ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q335=+Q37  ;NOMINAL DIAMETER ~
    Q342=+Q37  ;ROUGHING DIAMETER
89 M0
90 M3 MQ36
91 CALL LBL 11
92 LBL 0
93 * --- TAPP ----------------------
94 LBL 4
95 TOOL CALL Q10 Z SQ11
96 M9
97 Q15 = Q13 * 1
98 CYCL DEF 209 TAPPING W/ CHIP BRKG ~
    Q200=+5    ;SET-UP CLEARANCE ~
    Q201=+Q12  ;DEPTH OF THREAD ~
    Q239=+Q13  ;THREAD PITCH ~
    Q203=+0    ;SURFACE COORDINATE ~
    Q204=+50   ;2ND SET-UP CLEARANCE ~
    Q257=+Q15  ;DEPTH FOR CHIP BRKNG ~
    Q256=+Q13  ;DIST FOR CHIP BRKNG ~
    Q336=+0    ;ANGLE OF SPINDLE
99 L M140 MB MAX
100 L  X+0  Y+0 F8000 M3
101 L  Z+50 F5000
102 M0
103 MQ14
104 CALL LBL 11
105 LBL 0
106 * --------------------------------
107 L M140 MB MAX
108 M2
109 END PGM M12_SKD11 MM 

こんなデータをタップ径や材質ごとに用意しておくと、座標を編集するだけで
多種類のタップ加工簡単にができます。
ファナックでも、マクロを作成すれば同様のデータは作成できますが
制御機のサイクルだけで作成できるところが、ユーザーにとってはありがたい所だと思います

まとめ

一度、ハイデンハイン機を触ると、ファナック機には戻れないと言う意見をよく聞きます。
工具管理方法の違いもそうですが、このようなサイクルを制御機側が提供している点は
重要なポイントだと思います。
これは、高精度輪郭精度なども同じかもしれません。
機械メーカーの味付けで、同じNCデータを流しても、終了時間はかなりかわりますね。
機械メーカーにとっては、自由度があり、差別化ができていいのかもしれませんが
いろんなメーカーの機械を選択したい、ユーザー側としては、データの互換性は気になります。

工具補正指令　／　工具径・工具長

ＮＣプログラムは、既存の輪郭指令を利用して制御機側の設定で補正をかける事ができます。
この機能により、ＮＣプログラムの修正なしに、使用工具や加工状況に合わせた経路で動作させる事が可能になります。
ただし、補正をかけるコードは、互換性があまりありません。
ファナック系とＯＳＰでも違いますし、ハイデンハインやレダースでは工具管理方法の違いから、補正値を設定しておく補正番号などありません。
まずはファナックでの説明を元に、他の制御機にも触れていこうと思います。
補正には、工具径補正と工具長補正があります。
工具径補正は工具の径方向（製品のサイズ）の調整用です。
工具長補正は工具の長さ（製品の深さ）の調整用です。

工具径補正

図面を描く場合と違って、加工しようとすると、工具の径を考慮する必要があります。
工具径が事前にわかっている場合には、上図青線のように仕上がり寸法に対して、工具半径分オフセットした輪郭を定義する事で加工は可能になります。
ところが、工具径が不明な場合や加工精度が必要な場合には加工時の環境に合わせる必要があります。
その都度データを修正していたのでは大変なので、機械コントローラ側で調整できる仕様を工具径補正といいます。
工具径補正ができる仕様の制御機では、基本輪郭データは適当でいいことになりますが、一般的には２種類の方法で輪郭データを作成します。
一つは、 工具径を考慮しない 仕上がり寸法（図面通り）でデータを作成する方法です。
この場合、加工時の補正は、使用工具半径を入力する事になります。
二つ目は、予定の基本工具径を考慮して、その工具半径分オフセットした形状でデータを作成する方法です。
この場合、データ作成時の基本工具径と使用時の工具径の差を補正として入力します。
ここでは、前者の方法で、図面寸法でデータを作成する方法で説明します。

G41/G42/G40　／　工具径補正指令

補正を使用する際には、工具の進行方向を考慮する必要があります。
加工する場合の工具をイメージして、工具の進行方向の左側に工具が来るような補正には「G41」、工具進行方向の右側に工具が来る場合には「G42」の指令を使用します。
「G41/G42」は指定されたブロックから、次のブロックを先読みし移動方向（ベクトル）を認識してその方向に対して「右側・左側」へオフセットした工具経路が自動的に計算されます。
この工具経路のオフセットされた輪郭は「G40」コードが指令されるまで制御機により自動的に生成されます。
この指令により、「G41/G42」から「G40」までの工具経路は、補正として自動調整された経路となります。

「Ｇコード　グループ０７」
・G41　：　工具径補正左
・G42　：　工具径補正右
・G40　：　工具径補正キャンセル

では、補正量はどのようにして決定するのでしょうか？
これは、ファナック系とハイデンハイン・レダースでは方法が異なります。
ファナック系の場合は、「D」+「数字」で指令し、制御機で設定します。
例えば、「G01 G41 X10.0 Y20.3 D01F2000」の指令では、制御機の補正設定画面の「D01」の設定箇所に設定されている数値が補正量となります。
ハイデンハインやレダースでは、工具管理方法が違うので、工具が呼ばれた時点で工具径を認識するようになっています。
したがって、補正番号をわざわざ指定する必要はありません
「G01 G41 X10.0 Y20.3 F2000」でいいことになります。

スタートアップ・キャンセル／工具径補正

工具径補正は、「G41/G42」が指令されたブロックから次のブロックのベクトル（進行方向）を認識しそのベクトルの法線方向に工具補正量だけオフセットされたパス（経路）を自動生成します。
その時に注意が必要なのは、補正指令ブロックの直前の位置が重要です。
補正モードでない場合には、指令の座標位置へ移動しますが、補正モードではオフセットされた座標となりますから指令と違う座標へ移動するので思わぬ干渉が起きる場合があります

この例では、「P1 ⇒ P2 ⇒ P3 ⇒ P4 ⇒ P1」で製品の輪郭として定義してます。
加工に入る前に「P0」位置で工具を降し「P0 ⇒ P1」で工具径補正（G41)を指令します。
「P0」位置からいきなり製品輪郭へ移動させてます。
そうすると、 「P0 ⇒ P1」 へ移動する途中で制御機は次の動作（P1 ⇒ P2）の方向を先読みしその法線方向の座標を計算し、「P1」の座標を自動補正します。
これをスターアップ動作と呼びますが、スタート位置によっては、思わぬ食込みが発生する場合があります。
これは、「G40」を指令するキャンセルブロックでも同様で、キャンセル位置によっては食込みが発生します。
これをさける為には、オフセット決定する法線方向側の離れた位置をスタート位置（キャンセル位置）にするか、食込みが発生しないように、スターアップを考慮して輪郭を延長させたり、要素を追加したりします。

上図でＮＣプログラムを作成してみます。

%
 O1000
 G17G90G00
 G00X0Y0Z50.0
 X62.0Y0           (P0)
 Z5.0
 G01Z-10.0F300
 G41D01X24.0Y25.0F500 (P1)
 X40.0Y80.0        (P2)
 X70.0Y60.0        (P3)
 X75.0Y25.0        (P4)
 X24.0Y25.0        (P1)
 G40X62.0Y0        (P0)
 M30
 %

TRYCUTと言うソフトで、シミュレーションしてみます。
TRYCUTの補正設定画面にも工具径補正「D01」に、使用工具の半径を設定しています。

予想通り、「P0 ⇒ P1」のスタートアップ動作で「P1」付近で食込んでしまいました。

 X0Y0           (P0) 

スタート位置を「X0Y0」に修正し、もう一度シミュレーションかけてみます。

今度は、食込みませんでした。
このように、工具径補正を使用する場合には、スタートアップ（キャンセル）を意識する必要があります。
一般的には、輪郭要素へ直接アプローチせずに、進入円弧などを使用してスタートアップしたほうが安全です。
ＣＡＭによっては、補正を利用する場合、進入指令が必須なＣＡＭもあります。

%
 O1000
 G17G90G00
 G00X0Y0Z50.0
 X49.5Y15.0      
 Z5.0
 G01Z-10.0F300
 G41D01X59.5Y15.0F500 　(スタートアップ)　　
 G03X49.5Y25.0I-10.0    (進入円弧)
 G01X24.0Y25.0F500 
 X40.0Y80.0        
 X70.0Y60.0        
 X75.0Y25.0        
 X49.5        
 G03X39.5Y15.0J-10.0    (退出)
 G01G40X49.5Y15.0       (キャンセル)
 G00Z50.0
 M30
 %

工具径補正番号指令

工具径補正を利用する場合、その補正量を設定する必要がありますが、その設定方法は、コントローラによって違いがあります。
ここでは、もっとも一般的はファナック系とハイデンハイン、レダースでの設定方法を簡単に説明します。

ファナック／工具径補正番号

ファナック系では、前述のように、「G41またはG42」と共に「D」+「数字」（Ｄ番号）で設定します。
Ｄ番号は、制御機側にＤ番号の設定テーブルが用意されていて、そこに補正量を設定しておきます。
工具径補正指令があった場合、その補正量を参考にオフセット経路を自動計算します。
このように、ファナックでは使用工具と工具径補正の関連性はなく、Ｄ番号により管理されています。
これにより、ＮＣプログラムでＤ番号を変更する事で自由に補正量も変更できますが、Ｄ番号を間違えたり、設定値の入力ミスがあった場合には大変です。

ハイデンハイン・レダース／工具径補正

ハイデンハインやレダースは、工具管理にファナックよりも複雑なデータバースを使用しています。
このデータベースには、いろいろな情報が含まれていますが、必須な情報として「工具の長さ」「工具直径」が含まれています。
使用工具に対してこの情報を持っているため、工具径補正においてもファナックのようなＤ番号により補正量の設定は必要ありません。
また、「工具長」や「工具径」の情報は基本的に、自動工具測定装置から自動的に設定されます。
国産機と違いヨーロッパでは 自動工具測定装置は必須の考えがあるようです。
また、使用工具情報を元にする事から、自動工具交換装置「ATC」付きマシン（マシニングセンター）がターゲットだと思われます。

ハイデンハイン iTNC530 の工具径補正指令

ハイデンハインでは、「G41/G42」の代わりに「RL」(G41)、「RR」(G42) の指令を使用します。
「R0」が補正モードキャンセルです。
また、補正番号などはありません。
補正量は、呼び出した工具の管理テーブルに情報があります。
工具テーブルの「R」項目に基本的には工具半径が入力されていて、制御機はその値をもとにオフセットします。
さらに「DR」項目で追加の補正量を設定できます。
さらに、工具を呼び出すコマンド「TOOL CALL」行に「DR」で直接数値を追加できます。
補正量＝「D : Tool table」+「DR : Tool Table」+「DR : Tool Call」となりTool Table からだけでなく、工具交換指令のNCプログラムからでも調整できます。
上のファナックのＧコードを、ハイデン言語で表してみます。

0 BEGIN PGM 1001 MM
 L X+0 Y+0 R0 FMAX
 L Z+50 R0 FMAX
 L X+49.5 Y+15 R0 FMAX
 L Z+5 FMAX
 L Z-10 F300
 L X+59.5 RL F500
 CC X+49.5 Y+15
 C X+49.5 Y+25.0 DR+
 L X+24 Y+25
 L X+40 Y+80
 L X+70 Y+60
 L X+75 Y+25
 L X+49.5
 CC X+49.5 Y+15
 C X+39.5 Y+15.0 DR+ F1000
 L X+49.5 Y+15 R0
 L Z+50 FMAX
 END PGM 1001 MM

ハイデンハインでは、直線補間は「L」で指令しますので、G言語に対してL言語と呼ばれることもあります。

レダース RMS6 の工具径補正指令

レダース言語の、プログラム構文は上の二つとは全く違います。
ＮＣプログラムと言うよりは、プログラミング言語の「VB」や「JavaScript」に似ているように思います。
ただ、工具経路を指令する移動の指令は、ファナックのＧコードとハイデンハインのＬ言語の両方を理解できます。
したがって、座標系や工具交換、などの準備機能をレダース言語で指令すれば、加工の工具移動指令は、ファナックかハイデンハインのコードを若干編集する程度で使用できます。
下記では上のファナックのＧコードを、レダースが動作する言語で表してみます。

 G17 G90 G00
 SH
 CCI
 G00 X49.5 Y15.
 Z50.
 Z5.
 G01 Z-10. F300.
 G41 X59.5 F500.
 G03 X49.5 Y25. I-10.
 G01 X24.
 X40. Y80.
 X70. Y60.
 X75. Y25.
 X49.5
 G03 X39.5 Y15. J-10. F1000.
 G01 G40 X49.5
 G00 Z50.
 SH
 CCA
 M30

このように、ほとんどファナックと同様のコードが使用可能です。
これが、ハイデンハイン言語も同様に使用可なのは驚きです。
ただファナックと違うのは、工具径補正番号がありませんね。
こちらも。ハイデンハインと同様に工具管理データベースに工具径も登録されていて、補正は使用工具により自動的に設定できるためです

この仕様によって、工具交換後「Tdm -auto」の指令だけで補正量は決定されます。
補正量は、「G41/G42」指令により自動的に工具半径分がオフセットされます。
また、「G41 -R=0.02」のように、工具半径に補正量を追加することもできますし、工具半径が不明な場合には、その値が直接使用されます。
さらに、「SET_OFFSET_R」という指令を使うと、オフセット量を直接指定できます。
直接「 SET_OFFSET_R =5.02 -abs」とできますし、変数も使用可能です。
「$DIAM_」というシステム変数で、スピンドルにある実際の工具径がわかるので、その１/２に調整量を付加することで、補正量を調整したりできます。

・
・
$Offset_C = ($DIAM_)/2 + 0.05
SET_OFFSET_R=$Offset_C -abs
G01 G41 X59.5 Y0.0 F1000 
・
・

この指令で、実際の「工具半径 + 0.05」の補正を設定できます。

補正量をプログラムで管理する

このように、ハイデンハインやレダースの言語を見てみると、補正量はNCプログラムで定義するのが基本的な考え方のように思います。
対して、ファナック系では、コントローラ側の補正画面で設定するのが一般的です。
後者の場合、自由度はあがりますが入力忘れや入力ミスの場合、大きな被害がでる場合が考えられます。
特に、NCデータ作成側と、機械操作側が違う担当者の場合には、補正番号の伝達方法は重要になりますね。
完全でなくても、安全率を見込んだ補正量はNCプログラムに定義しておいたほうが安心だと思います。
もちろん、ファナックの場合でも、システム変数を利用すれば同様の事ができます。
具体的には、「G10」のコードや「#11001～」や「#2201～」のシステム変数に代入することで定義できます
ただし、この大事な変数が制御機のバージョンやオプションによって番号が変わってしまうは、困ったもんです。

まとめ

今回は、工具径補正の説明をしました。
ファナック系だけではく、ハイデンハインやレダースの指令も簡単に紹介しました。
一番の違いは、工具径補正番号（D番号）の有無ですね。
利用方法によって、いろいろな意見があると思いますが、自動化を目指そうと思うと、工具を持ってきただけで、基準の補正量が決定できる仕様が有利だと思っています。

ＮＣプログラムの記事